Obtendo informações da CPU em Delphi

Publiquei em Maio um post a respeito da obtenção do MAC Address em Delphi para gerar um código que identificasse um computador de forma única. Naquela ocasião, sugeri que se incluisse informações sobre a CPU para melhorar o código obtido. Então, vou mostrar aqui como obter essas informações.

A primeira coisa a saber é que as informações sobre a CPU são obtidas através de uma instrução assembly chamada CPUID. Prepare a escova de bits!

A instrução CPUID usa o registrador EAX para determinar que tipo de informação deve ser retornado. Por exemplo, quando o EAX está com valor 0 (zero), CPUID retorna um texto de 12 caracteres com a identificação do fabricante da CPU. No exemplo que segue, uso o comando ASM do Delphi para submeter as instruções assembly.

var VendorID : array[0..12] of char;
begin
Asm
// Isso faz com que EAX tenha valor zero
XOR EAX, EAX

// Chama a instrução CPUID
CPUID

// Retorna 4 caracteres em cada um
// dos registradores EBX, EDX e ECX,
// totalizando 12 caracteres do ID
// do fabricante.
MOV dword ptr [VendorID], EBX
MOV dword ptr [VendorID+4], EDX
MOV dword ptr [VendorID+8], ECX
end;
// Como no C++, terminar com zero
VendorID[12] := Char(0);

Para obter o tipo, o modelo, a família e o stepping do processador, devemos usar EAX com valor 1. O stepping identifica melhorias do mesmo processador, sendo a primeira sempre A0 e nas releases seguintes há acréscimos no número e/ou na letra. O tipo mostra se o processador é Original, OverDrive ou Dual. Modelo e família são numerações dadas pelos fabricantes a cada versão de seus chips. O retorno desses valores se dá no próprio EAX.

Quando chamamos CPUID com o valor de EAX igual a 1, outras informações são retornadas em outros registradores. Em EDX e ECX são retornadas indicações da presença de recursos da CPU. Informações sobre recursos extras são colocados em EBX. O trecho abaixo mostra como recuperar a assinatura da CPU (tipo + modelo + familia + stepping) além de reportar a presença de FPU (Floating Point Unit, que é o coprocessador matemático), se o processador possui tecnologia MMX (melhora processamentos envolvendo multimedia) e, no caso do processador ser Intel, se ele é HTT (Hyper Thread Technology, isto é, se há emulação de mais processadores).

var retStr, dType : String;
REGEAX, REGEBX, REGEDX : LongWord;
dLogicalProcessorCount : integer;
dFamily, dModel, dStepping, dFamilyEx, dModelEx : integer;
hasFpu, hasMmx, hasHtt : boolean;
begin
asm
MOV EAX, 1
CPUID
MOV [REGEAX], EAX
MOV [REGEBX], EBX
MOV [REGEDX], EDX
end;

dFamily := ((REGEAX shr 8) and $F);
dModel := ((REGEAX shr 4) and $F);
dStepping := (REGEAX and $F);

dFamilyEx := ((REGEAX shr 20) and $FF);
dModelEx := ((REGEAX shr 16) and $F);

case (((REGEAX shr 12) and $7)) of
0: dType := 'Original';
1: dType := 'OverDrive';
2: dType := 'Dual';
end;

hasFpu := ((REGEDX and $00000001) <> 0);
hasMmx := ((REGEDX and $00800000) <> 0);
hasHtt := ((REGEDX and $10000000) <> 0);

if ((StrComp(VendorID, 'GenuineIntel') = 0) And HasHTT) then
dLogicalProcessorCount := ((REGEBX shr 16) and $FF)
else
dLogicalProcessorCount := -1;

retStr := dType +
IntToStr (dFamily) + IntToStr (dModel) +
IntToHex (dStepping, 2) +
IntToStr (dFamilyEx) + IntToStr (dModelEx);

Tenho uma lista maior com mapeando os valores retornados em EDX com os recursos possívels. Caso julguem interessante, coloco em outro post esta lista.

Mais Informações
Instrução CPUID, Obtendo MAC Address em Delphi